Files
update-notify/PKGBUILD
T
Daniele Fucini 3ebded0476 Update PKGBUILD
Bump to 3.4, install the README, and quote the source entry.
2026-10-14 13:09:05 +02:00

30 lines
1.0 KiB
Bash

# PKGBUILD
# Maintainer: Daniele Fucini <dfucini [at] gmail [dot] com>
pkgname=update-notify
pkgver=3.4
pkgrel=1
pkgdesc='Notify when updates are available'
arch=('any')
url="https://git.shouldnt.work/fuxino/${pkgname}"
license=('GPL-3.0-or-later')
depends=('pacman-contrib'
'libnotify')
makedepends=('git')
optdepends=('aurutils: to check AUR packages in the local repo for updates'
'fwupd: to check for firmware updates'
'git-monitor: to check git repos for updates')
source=("git+${url}?signed#tag=${pkgver}")
validpgpkeys=('7E12BC1FF3B6EDB2CD8053EB981A2B2A3BBF5514')
sha256sums=('12a68498d50871264f4a0ed082ff29a361676cf134c43520f98ee3f287e45509')
package()
{
cd "${srcdir}/${pkgname}"
install -Dm755 "${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 "${pkgname}.service" "${pkgdir}/usr/lib/systemd/user/${pkgname}.service"
install -Dm644 "${pkgname}.timer" "${pkgdir}/usr/lib/systemd/user/${pkgname}.timer"
install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
}