# PKGBUILD

# Maintainer: Daniele Fucini <dfucini [at] gmail [dot] com>

pkgname=update-notify
pkgver=3.6
pkgrel=1
pkgdesc='Notify when updates are available'
arch=('any')
url="https://git.shouldnt.work/fuxino/$pkgname"
license=('GPL-3.0-or-later')
depends=('pacman-contrib'
         'libnotify')
makedepends=('git')
optdepends=('aurutils: to check AUR packages in the local repo for updates'
            'fwupd: to check for firmware updates'
            'git-monitor: to check git repos for updates')
source=("git+$url?signed#tag=$pkgver")
validpgpkeys=('7E12BC1FF3B6EDB2CD8053EB981A2B2A3BBF5514')
sha256sums=('3efd5deadb6619b0fbc46d0559716feb117d095ce1068a02da53c3e14e88af68')

package()
{
    cd "$srcdir"/"$pkgname"
    install -Dm755 "$pkgname" "$pkgdir"/usr/bin/"$pkgname"
    install -Dm644 "$pkgname".service "$pkgdir"/usr/lib/systemd/user/"$pkgname".service
    install -Dm644 "$pkgname".timer "$pkgdir"/usr/lib/systemd/user/"$pkgname".timer
    install -Dm644 README.md "$pkgdir"/usr/share/doc/"$pkgname"/README.md
    install -Dm644 config.example "$pkgdir"/usr/share/doc/"$pkgname"/config.example
}