# Maintainer: Daniele Fucini <dfucini [at] gmail [dot] com>

pkgname=calcurse-gcal
pkgver=0.1.0
pkgrel=1
pkgdesc='Sync calcurse with Google Calendar: timer, UI hooks, login renewal, notifications and an xmobar indicator'
arch=('any')
url="https://git.shouldnt.work/fuxino/$pkgname"
license=('GPL-3.0-or-later')
depends=('bash'
         'calcurse'
         'libnotify'
         'procps-ng'
         'python'
         'python-httplib2'
         'python-oauth2client')
makedepends=('git')
source=("git+$url?signed#tag=$pkgver")
validpgpkeys=('7E12BC1FF3B6EDB2CD8053EB981A2B2A3BBF5514')
sha256sums=('SKIP')

package()
{
    cd "$srcdir"/"$pkgname"
    for bin in calcurse-sync calcurse-relogin calcurse-today calcurse-xmobar; do
        install -Dm755 "$bin" "$pkgdir"/usr/bin/"$bin"
    done
    for unit in calcurse-sync.service calcurse-sync.timer calcurse-today.service calcurse-today.timer \
                calcurse-relogin.service; do
        install -Dm644 "$unit" "$pkgdir"/usr/lib/systemd/user/"$unit"
    done
    install -Dm755 hooks/pre-load "$pkgdir"/usr/share/"$pkgname"/hooks/pre-load
    install -Dm755 hooks/post-save "$pkgdir"/usr/share/"$pkgname"/hooks/post-save
    install -Dm644 config.example "$pkgdir"/usr/share/doc/"$pkgname"/config.example
    install -Dm644 README.md "$pkgdir"/usr/share/doc/"$pkgname"/README.md
}
